----------------------------------------------------------------------------------
-- Company:  INSA-Toulouse
-- Engineer: Paul Faure
-- 
-- Create Date: 09.07.2021 09:54:12
-- Module Name: ScreenDriver - Behavioral
-- Project Name: Processeur sécurisé
-- Target Devices: Basys 3 ARTIX7
-- Tool Versions: Vivado 2016.4
--
-- Description: Fait le lien entre le processeur et l'écran 
-- 
-- Dependencies: None
--
-- Comments: Gère la conversion des entiers en hexa pour l'affichage
----------------------------------------------------------------------------------


library IEEE;
use IEEE.STD_LOGIC_1164.ALL;
use IEEE.STD_LOGIC_UNSIGNED.ALL;
use IEEE.NUMERIC_STD.ALL;

entity ScreenDriver is
    Generic ( Nb_bits : Natural
            );
    Port ( CLK : in STD_LOGIC;

           Value : in STD_LOGIC_VECTOR (Nb_Bits - 1 downto 0);   -- ********************************
           ValueAv : in STD_LOGIC;                               -- ***** Depuis le processeur *****
           IsInt : in STD_LOGIC;                                 -- ********************************

           OutData : out STD_LOGIC_VECTOR (0 to 6);              -- ********************************
           OutDataAv : out STD_LOGIC);                           -- ********* Vers l'écran *********
end ScreenDriver;

architecture Behavioral of ScreenDriver is

		-- Signal pour récupérer la valeur entière
    signal intern_value : STD_LOGIC_VECTOR (Nb_Bits - 1 downto 0) := (others => '0');
		-- 4 bits actuellement en cours de conversion
    signal current_hexa : STD_LOGIC_VECTOR (3 downto 0) := (others => '0');

		-- Type pour gérer l'avancement dans la conversion
    subtype compteur_T is Integer range -2 to Nb_bits/4 - 1;
		-- Signal comptant l'avancement dans la conversion (début a -2, affichage de "0x" puis début de la conversion avec compteur = 0)
    signal compteur : compteur_T := -2;
		-- Si un digit non nul a été detecté
    signal first_detected : BOOLEAN := false;
     
    
    constant Code_ASCII_Zero : STD_LOGIC_VECTOR (0 to 6) := "0110000";
    

begin
		-- Récupération des 4 bits en cours de conversion
    current_hexa <= intern_value(Nb_Bits - 1 - compteur * 4 downto Nb_Bits - compteur * 4 - 4) when compteur >= 0 and compteur < Nb_Bits else "0000";

    process
    begin
        wait until CLK'event and CLK = '1';
				
        if ValueAv = '1' then  
						-- Si on a une donnée en entier 
            if IsInt = '0' then
								-- Si c'est un char on la répercute juste 
                OutData <= Value (6 downto 0);
            else 
								-- Si c'est un entier, on récupère la valeur et affiche le 0
                intern_value <= Value;
                OutData <= Code_ASCII_Zero;
                compteur <= compteur + 1;
            end if;
						-- On signal a l'écran qu'il faut afficher
            OutDataAv <= '1';
        elsif compteur = -1 then
						-- Si une conversion est en cours a l'étape -1, on affiche x
            OutData <= "1111000";
            compteur <= compteur + 1;
        elsif compteur >= 0 then
						-- Si on est en phase de conversion 
            if (current_hexa >= "0000" and current_hexa <= "1001") then
								-- Si on est sur un chiffre (0-9)
                if (not(current_hexa = "0000") or first_detected or compteur = Nb_bits/4 - 1 ) then
										-- On l'affiche si ce n'est pas 0, ou qu'un digit a déjà été detecté, ou qu'il s'agit du dernier digit de l'entier
                    OutData <= "011" & current_hexa;
                    OutDataAv <= '1';
                    first_detected <= true;
                else
										-- Sinon, le digit est un 0 inutile, on ne l'affiche pas
                    OutDataAv <= '0';
                end if;
            else 
								-- Si on est sur une lettre (A-F), on l'affiche
                OutData <= ("000" & current_hexa) + "0110111";
                OutDataAv <= '1';
                first_detected <= true;
            end if;
        
						
            if (compteur = Nb_bits/4 - 1) then
								-- Si la conversion est finie on réinitialise
                compteur <= -2;   
                first_detected  <= false;
            else 
								-- Sinon on avance le compteur
                compteur <= compteur + 1;
            end if;
        else
            OutDataAv <= '0';
        end if;
    end process;

end Behavioral;